# CONFIG += no_poppler
CONFIG += console
TEMPLATE = app
TARGET = pykit
DEPENDPATH += .
INCLUDEPATH += .
QT += webkit network gui core

isEmpty(PYTHON) {
    PYTHON = python
}
isEmpty(PYTHONCONFIG) {
    PYTHONCONFIG = $${PYTHON}-config
}

isEmpty(LIBBOOSTPYTHON) {
    LIBBOOSTPYTHON = boost_python
}

# boost_python
LIBS += -l$${LIBBOOSTPYTHON}

# python
isEmpty(LIBPYTHON) {
    QMAKE_CXXFLAGS += $$system($$PYTHONCONFIG --cflags)
    QMAKE_CXXFLAGS -= -Wstrict-prototypes
    LIBS += $$system($$PYTHONCONFIG --ldflags)
}
else {
    LIBS += -l$$LIBPYTHON
}

mac {
    # Qt is not available as univeral library and provides
    # a correct -arch tag automatically
    QMAKE_CXXFLAGS -= -arch ppc x86_64 i386
    QMAKE_CFLAGS -= -arch ppc x86_64 i386
}

win32 {
    QMAKE_CXXFLAGS += -fno-strict-aliasing
}

# Input
HEADERS += MainWindow.hh \
           Publisher.hh \
           PythonPublisher.hh \
           Viewer.hh
SOURCES += main.cc \
           MainWindow.cc \
           Publisher.cc \
           PythonPublisher.cc \
           Viewer.cc

# poppler
!no_poppler {
    LIBS += -lpoppler-qt4 -lpoppler
    HEADERS += PDFWidget.hh
    SOURCES += PDFWidget.cc
    DEFINES += POPPLER
}