# CONFIG += no_poppler
# CONFIG += no_webkit
# CONFIG += console
CONFIG += windows
TEMPLATE = app
TARGET = pykit
DEPENDPATH += .
INCLUDEPATH += .
QT += network gui core

# Used to manually link against latest webkit
!no_webkit {
    QT += webkit
}

isEmpty(PYTHON) {
    PYTHON = python
}
isEmpty(PYTHONCONFIG) {
    PYTHONCONFIG = $${PYTHON}-config
}

isEmpty(LIBBOOSTPYTHON) {
    LIBBOOSTPYTHON = boost_python
}

# boost_python
LIBS += -l$${LIBBOOSTPYTHON}

# python
isEmpty(LIBPYTHON) {
    QMAKE_CXXFLAGS += $$system($$PYTHONCONFIG --cflags)
    QMAKE_CXXFLAGS -= -Wstrict-prototypes
    LIBS += $$system($$PYTHONCONFIG --ldflags)
}
else {
    LIBS += -l$$LIBPYTHON
}

mac {
    QMAKE_CXXFLAGS -= -arch ppc x86_64 i386
    QMAKE_CFLAGS -= -arch ppc x86_64 i386
}

win32 {
    QMAKE_CXXFLAGS += -fno-strict-aliasing
}

# Input
HEADERS += MainWindow.hh \
           Publisher.hh \
           PythonPublisher.hh \
           Viewer.hh
SOURCES += main.cc \
           MainWindow.cc \
           Publisher.cc \
           PythonPublisher.cc \
           Viewer.cc

# poppler
!no_poppler {
    LIBS += -lpoppler-qt4 -lpoppler
    HEADERS += PDFWidget.hh
    SOURCES += PDFWidget.cc
    DEFINES += POPPLER
}