pykit.pro

   1 # CONFIG += no_poppler
   2 # CONFIG += no_webkit
   3 # CONFIG += console
   4 CONFIG += windows
   5 TEMPLATE = app
   6 TARGET = pykit
   7 DEPENDPATH += .
   8 INCLUDEPATH += .
   9 QT += network gui core svg
  10
  11 # Used to manually link against latest webkit
  12 !no_webkit {
  13     QT += webkit
  14 }
  15
  16 isEmpty(PYTHON) {
  17     PYTHON = python
  18 }
  19 isEmpty(PYTHONCONFIG) {
  20     PYTHONCONFIG = $${PYTHON}-config
  21 }
  22
  23 isEmpty(LIBBOOSTPYTHON) {
  24     LIBBOOSTPYTHON = boost_python
  25 }
  26
  27 # boost_python
  28 LIBS += -l$${LIBBOOSTPYTHON}
  29
  30 # python
  31 isEmpty(LIBPYTHON) {
  32     QMAKE_CXXFLAGS += $$system($$PYTHONCONFIG --cflags)
  33     QMAKE_CXXFLAGS -= -Wstrict-prototypes
  34     LIBS += $$system($$PYTHONCONFIG --ldflags)
  35     # OUCH ... on Mac we sometimes have multiple python versions (in this case MacPorts and native)
  36     # We need to explicitly specify the path as to link against the correct Version
  37     LIBS -= $$system($$PYTHONCONFIG --libs | sed -e "'s/.*\\\\(-lpython[0-9.]*\\\\\).*/\\\\1/'")
  38     LIBS += $$system(ls `$$PYTHONCONFIG --ldflags | sed -e "'s/.*-L\\\\([^ ]*\\\\).*/\\\\1/'"`/lib`$$PYTHONCONFIG --libs  | sed -e "'s/.*-l\\\\(python[0-9.]*\\\\).*/\\\\1/'"`* | tail -1)
  39 }
  40 else {
  41     LIBS += -l$$LIBPYTHON
  42 }
  43
  44 mac {
  45     QMAKE_CXXFLAGS += -mmacosx-version-min=10.4
  46     QMAKE_CXXFLAGS -= -arch ppc x86_64 i386
  47 }
  48
  49 win32 {
  50     QMAKE_CXXFLAGS += -fno-strict-aliasing
  51 }
  52
  53 # Input
  54 HEADERS += MainWindow.hh \
  55            Publisher.hh \
  56            PythonPublisher.hh \
  57            PythonHTTP.hh \
  58            Viewer.hh
  59 SOURCES += main.cc \
  60            MainWindow.cc \
  61            Publisher.cc \
  62            PythonPublisher.cc \
  63            PythonHTTP.cc \
  64            Viewer.cc
  65
  66 # poppler
  67 !no_poppler {
  68     LIBS += -lpoppler-qt4 -lpoppler
  69     HEADERS += PDFWidget.hh
  70     SOURCES += PDFWidget.cc
  71     DEFINES += POPPLER
  72 }