pykit.pro

   1 # CONFIG += no_poppler
   2 CONFIG += console
   3 TEMPLATE = app
   4 TARGET = pykit
   5 DEPENDPATH += .
   6 INCLUDEPATH += .
   7 QT += webkit network gui core
   8
   9 isEmpty(PYTHON) {
  10     PYTHON = python
  11 }
  12 isEmpty(PYTHONCONFIG) {
  13     PYTHONCONFIG = $${PYTHON}-config
  14 }
  15
  16 isEmpty(LIBBOOSTPYTHON) {
  17     LIBBOOSTPYTHON = boost_python
  18 }
  19
  20 # boost_python
  21 LIBS += -l$${LIBBOOSTPYTHON}
  22
  23 # python
  24 isEmpty(LIBPYTHON) {
  25     QMAKE_CXXFLAGS += $$system($$PYTHONCONFIG --cflags)
  26     QMAKE_CXXFLAGS -= -Wstrict-prototypes
  27     LIBS += $$system($$PYTHONCONFIG --ldflags)
  28 }
  29 else {
  30     LIBS += -l$$LIBPYTHON
  31 }
  32
  33 mac {
  34     # Qt is not available as univeral library and provides
  35     # a correct -arch tag automatically
  36     QMAKE_CXXFLAGS -= -arch ppc x86_64 i386
  37     QMAKE_CFLAGS -= -arch ppc x86_64 i386
  38 }
  39
  40 win32 {
  41     QMAKE_CXXFLAGS += -fno-strict-aliasing
  42 }
  43
  44 # Input
  45 HEADERS += MainWindow.hh \
  46            Publisher.hh \
  47            PythonPublisher.hh \
  48            Viewer.hh
  49 SOURCES += main.cc \
  50            MainWindow.cc \
  51            Publisher.cc \
  52            PythonPublisher.cc \
  53            Viewer.cc
  54
  55 # poppler
  56 !no_poppler {
  57     LIBS += -lpoppler-qt4 -lpoppler
  58     HEADERS += PDFWidget.hh
  59     SOURCES += PDFWidget.cc
  60     DEFINES += POPPLER
  61 }