pykit.pro

   1 # CONFIG += no_poppler
   2 CONFIG += console
   3 TEMPLATE = app
   4 TARGET = pykit
   5 DEPENDPATH += .
   6 INCLUDEPATH += .
   7 QT += webkit network gui core
   8
   9 isEmpty(PYTHON) {
  10     PYTHON = python
  11 }
  12 isEmpty(PYTHONCONFIG) {
  13     PYTHONCONFIG = $${PYTHON}-config
  14 }
  15
  16 isEmpty(LIBBOOSTPYTHON) {
  17     LIBBOOSTPYTHON = boost_python
  18 }
  19
  20 # boost_python
  21 LIBS += -l$${LIBBOOSTPYTHON}
  22
  23 # python
  24 isEmpty(LIBPYTHON) {
  25     QMAKE_CXXFLAGS += $$system($$PYTHONCONFIG --cflags)
  26     QMAKE_CXXFLAGS -= -Wstrict-prototypes
  27     LIBS += $$system($$PYTHONCONFIG --ldflags)
  28 }
  29 else {
  30     LIBS += -l$$LIBPYTHON
  31 }
  32
  33 mac {
  34     # Qt is not available as univeral library and provides
  35     # a correct -arch tag automatically
  36     QMAKE_CXXFLAGS -= -arch ppc x86_64 i386
  37     QMAKE_CFLAGS -= -arch ppc x86_64 i386
  38 }
  39
  40 # Input
  41 HEADERS += MainWindow.hh \
  42            Publisher.hh \
  43            PythonPublisher.hh \
  44            Viewer.hh
  45 SOURCES += main.cc \
  46            MainWindow.cc \
  47            Publisher.cc \
  48            PythonPublisher.cc \
  49            Viewer.cc
  50
  51 # poppler
  52 !no_poppler {
  53     LIBS += -lpoppler-qt4 -lpoppler
  54     HEADERS += PDFWidget.hh
  55     SOURCES += PDFWidget.cc
  56     DEFINES += POPPLER
  57 }