doclib/html-munge.xsl

   1 <?xml version="1.0" encoding="utf-8"?>\r
   2 <xsl:stylesheet version="1.0"\r
   3   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"\r
   4   xmlns:str="http://exslt.org/strings"\r
   5   extension-element-prefixes="str">\r
   6 \r
   7   <xsl:output \r
   8     method="html" \r
   9     encoding="html" \r
  10     doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN"\r
  11     doctype-system="http://www.w3.org/TR/html4/loose.dtd"/>\r
  12 \r
  13   <xsl:param name="topdir" select="''"/>\r
  14   \r
  15   <xsl:template match="*" name="copy">\r
  16     <xsl:copy>\r
  17       <xsl:call-template name="copy-attributes"/>\r
  18       <xsl:apply-templates/>\r
  19     </xsl:copy>\r
  20   </xsl:template>\r
  21 \r
  22   <xsl:template name="copy-attributes">\r
  23     <xsl:for-each select="@*">\r
  24       <xsl:attribute name="{name(current())}">\r
  25         <xsl:choose>\r
  26           <xsl:when test="contains(current(),'@TOPDIR@')">\r
  27             <xsl:value-of select="substring-before(current(),'@TOPDIR@')"/>\r
  28             <xsl:value-of select="$topdir"/>\r
  29             <xsl:value-of select="substring-after(current(),'@TOPDIR@')"/>\r
  30           </xsl:when>\r
  31           <xsl:otherwise>\r
  32             <xsl:value-of select="current()"/>\r
  33           </xsl:otherwise>\r
  34         </xsl:choose>\r
  35       </xsl:attribute>\r
  36     </xsl:for-each>\r
  37   </xsl:template>\r
  38 \r
  39   <!-- Replace @TOPDIR@ with relative top directory path -->\r
  40 \r
  41   <xsl:template match="@*[contains(current(),'@TOPDIR@')]">\r
  42     <xsl:value-of select="substring-before(current(),'@TOPDIR@')"/>\r
  43     <xsl:value-of select="$topdir"/>\r
  44     <xsl:value-of select="substring-after(current(),'@TOPDIR@')"/>\r
  45   </xsl:template>\r
  46   \r
  47   <!-- Add 'class' attribute  -->\r
  48   \r
  49   <xsl:template name="add-class">\r
  50     <xsl:param name="class"/>\r
  51     <xsl:copy>\r
  52       <xsl:call-template name="copy-attributes"/>\r
  53       <xsl:attribute name="class"><xsl:value-of select="$class"/></xsl:attribute>\r
  54       <xsl:apply-templates/>\r
  55     </xsl:copy>\r
  56   </xsl:template>\r
  57 \r
  58   <!-- Add '<br/>' tag after every ', ' -->\r
  59   <!-- This code is not very robust, it works with the doxygen output though -->\r
  60 \r
  61   <xsl:template name="break-comma">\r
  62     <xsl:copy>\r
  63       <xsl:call-template name="copy-attributes"/>\r
  64       <xsl:attribute name="class">commalist</xsl:attribute>\r
  65       <xsl:apply-templates mode="break-comma"/>\r
  66     </xsl:copy>\r
  67   </xsl:template>\r
  68  \r
  69   <xsl:template match="text()[1]" mode="break-comma">\r
  70     <xsl:value-of select="current()"/><br/>\r
  71   </xsl:template>\r
  72 \r
  73   <xsl:template match="*" mode="break-comma">\r
  74     <xsl:call-template name="copy"/>\r
  75   </xsl:template>\r
  76 \r
  77   <xsl:template match="text()[contains(current(),' and') or contains(current(),'and ')]" mode="break-comma" priority="1">\r
  78     <xsl:value-of select="substring-before(current(),'and')"/>\r
  79     <br/>\r
  80     <xsl:value-of select="substring-after(current(),'and')"/>\r
  81   </xsl:template>\r
  82 \r
  83   <xsl:template match="text()[contains(current(),',')]" mode="break-comma">\r
  84     <xsl:value-of select="substring-before(current(),',')"/>\r
  85     <xsl:text>,</xsl:text><br/>\r
  86     <xsl:value-of select="substring-after(current(),',')"/>\r
  87   </xsl:template>\r
  88 \r
  89   <!-- ====================================================================== -->\r
  90 \r
  91   <!-- Hack Glossary menu highlight -->\r
  92 \r
  93   <xsl:template match="div[@class='tabs menu']/ul[1]">\r
  94     <xsl:choose>\r
  95       <xsl:when test="//h1[.//text()='Glossary']">\r
  96         <xsl:call-template name="add-class">\r
  97           <xsl:with-param name="class">glossary</xsl:with-param>\r
  98         </xsl:call-template>\r
  99       </xsl:when>\r
 100       <xsl:otherwise>\r
 101         <xsl:copy>\r
 102           <xsl:call-template name="copy-attributes"/>\r
 103           <xsl:apply-templates/>\r
 104         </xsl:copy>\r
 105       </xsl:otherwise>\r
 106     </xsl:choose>\r
 107   </xsl:template>\r
 108 \r
 109   <!-- Autogenerate table-of-contents for a page -->\r
 110 \r
 111   <xsl:template match="div[@id='autotoc']">\r
 112     <xsl:copy>\r
 113       <xsl:call-template name="copy-attributes"/>\r
 114       <h1>Contents</h1>\r
 115       <ul>\r
 116         <xsl:for-each select="following::h2|following::h3|following::h4">\r
 117           <xsl:element name="li">\r
 118             <xsl:attribute name="class">\r
 119               <xsl:value-of select="concat('level_',local-name())"/>\r
 120             </xsl:attribute>\r
 121             <b><xsl:call-template name="section-number"/><xsl:text> </xsl:text></b>\r
 122             <xsl:element name="a">\r
 123               <xsl:choose>\r
 124                 <xsl:when test="a/@name">\r
 125                   <xsl:attribute name="href">\r
 126                     <xsl:value-of select="concat('#',a/@name)"/>\r
 127                   </xsl:attribute>\r
 128                 </xsl:when>\r
 129                 <xsl:otherwise>\r
 130                   <xsl:attribute name="href">\r
 131                     <xsl:text>#autotoc-</xsl:text>\r
 132                     <xsl:call-template name="section-number"/>\r
 133                   </xsl:attribute>\r
 134                 </xsl:otherwise>\r
 135               </xsl:choose>\r
 136               <xsl:value-of select="string(current())"/>\r
 137             </xsl:element>\r
 138           </xsl:element>\r
 139         </xsl:for-each>\r
 140       </ul>\r
 141     </xsl:copy>\r
 142   </xsl:template>\r
 143 \r
 144   <xsl:template name="section-number">\r
 145     <xsl:number level="any" from="div[@id='autotoc']" count="h2"/>\r
 146     <xsl:text>.</xsl:text>\r
 147     <xsl:if test="self::h3|self::h4">\r
 148       <xsl:number level="any" from="h2" count="h3"/>\r
 149       <xsl:text>.</xsl:text>\r
 150     </xsl:if>\r
 151     <xsl:if test="self::h4">\r
 152       <xsl:number level="any" from="h3" count="h4"/>\r
 153       <xsl:text>.</xsl:text>\r
 154     </xsl:if>\r
 155   </xsl:template>\r
 156   \r
 157   <xsl:template match="h2|h3|h4">\r
 158     <xsl:copy>\r
 159       <xsl:call-template name="copy-attributes"/>\r
 160       <xsl:choose>\r
 161         <xsl:when test="preceding::div[@id='autotoc']">\r
 162           <xsl:call-template name="section-number"/>\r
 163           <xsl:text> </xsl:text>\r
 164           <xsl:choose>\r
 165             <xsl:when test="a">\r
 166               <xsl:apply-templates/>\r
 167             </xsl:when>\r
 168             <xsl:otherwise>\r
 169               <xsl:element name="a">\r
 170                 <xsl:attribute name="class"><xsl:text>anchor</xsl:text></xsl:attribute>\r
 171                 <xsl:attribute name="name">\r
 172                   <xsl:text>autotoc-</xsl:text>\r
 173                   <xsl:call-template name="section-number"/>\r
 174                 </xsl:attribute>\r
 175                 <xsl:apply-templates/>\r
 176               </xsl:element>\r
 177             </xsl:otherwise>\r
 178           </xsl:choose>\r
 179         </xsl:when>\r
 180         <xsl:otherwise>\r
 181           <xsl:apply-templates/>\r
 182         </xsl:otherwise>\r
 183       </xsl:choose>\r
 184     </xsl:copy>\r
 185   </xsl:template>\r
 186 \r
 187   <!-- Build dia image-map from special div/span elements -->\r
 188   <xsl:template match="div[@class='diamap']">\r
 189     <xsl:element name="map">\r
 190       <xsl:attribute name="name"><xsl:value-of select="@name"/></xsl:attribute>\r
 191       <xsl:for-each select="span">\r
 192         <xsl:if test="a">\r
 193           <xsl:variable name="name" select="string(a[1])"/>\r
 194           <xsl:element name="area">\r
 195             <xsl:attribute name="shape">rect</xsl:attribute>\r
 196             <xsl:attribute name="alt"><xsl:value-of select="$name"/></xsl:attribute>\r
 197             <xsl:attribute name="title"><xsl:value-of select="$name"/></xsl:attribute>\r
 198             <xsl:attribute name="href"><xsl:value-of select="a[1]/@href"/></xsl:attribute>\r
 199             <xsl:attribute name="coords"><xsl:value-of select="@coords"/></xsl:attribute>\r
 200           </xsl:element>\r
 201         </xsl:if>\r
 202       </xsl:for-each>\r
 203     </xsl:element>\r
 204   </xsl:template>\r
 205 \r
 206   <!-- Reformat detailed member documentation -->\r
 207 \r
 208   <xsl:template match="table[@class='memname'][contains(preceding::h1[1],' Class ')][contains(preceding::h1[1],' Reference')]">\r
 209     <xsl:variable name="name"><xsl:value-of select="str:split(tr/td[@class='memname'],'::')[position()=last()]"/></xsl:variable>\r
 210     <table class="memname">\r
 211       <tr>\r
 212         <td class="memtype" colspan="5">\r
 213           <xsl:for-each select="tr/td[@class='memname']/*|tr/td[@class='memname']/text()">\r
 214             <xsl:choose>\r
 215               <xsl:when test="position()=last()">\r
 216                 <xsl:value-of select="substring(.,1,string-length(.)-string-length($name))"/>\r
 217               </xsl:when>\r
 218               <xsl:otherwise>\r
 219                 <xsl:copy-of select="."/>\r
 220               </xsl:otherwise>\r
 221             </xsl:choose>\r
 222           </xsl:for-each>\r
 223         </td>\r
 224       </tr>\r
 225 \r
 226       <xsl:choose>\r
 227         <xsl:when test="tr/td[@class='paramtype']">\r
 228           <tr>\r
 229             <td class="memname"><xsl:copy-of select="$name"/></td>\r
 230             <td class="memparen">(</td>\r
 231             <xsl:copy-of select="tr[1]/td[@class='paramtype']"/>\r
 232             <xsl:copy-of select="tr[1]/td[@class='paramname']"/>\r
 233             <td class="memparen"><xsl:if test="not(tr[td[@class='paramkey']])">)</xsl:if></td>\r
 234           </tr>\r
 235 \r
 236           <xsl:for-each select="tr[td[@class='paramkey']]">\r
 237             <tr>\r
 238               <td class="memname"></td>\r
 239               <td class="memparen"></td>\r
 240               <xsl:copy-of select="td[@class='paramtype']"/>\r
 241               <xsl:copy-of select="td[@class='paramname']"/>\r
 242               <td class="memparen"><xsl:if test="position()=last()">)</xsl:if></td>\r
 243             </tr>\r
 244           </xsl:for-each>\r
 245         </xsl:when>\r
 246         <xsl:otherwise>\r
 247           <tr>\r
 248             <td class="memname"><xsl:copy-of select="$name"/></td>\r
 249             <td class="memparen"><xsl:if test="tr/td[.='(']">()</xsl:if></td>\r
 250             <td class="paramtype"></td>\r
 251             <td class="paramname"></td>\r
 252             <td class="memparen"></td>\r
 253           </tr>\r
 254         </xsl:otherwise>\r
 255       </xsl:choose>\r
 256       <tr>\r
 257         <td colspan="5" class="memattrs"><xsl:copy-of select="tr/td[@width='100%']/code"/></td>\r
 258       </tr>\r
 259     </table>\r
 260   </xsl:template>\r
 261 \r
 262   <!-- Add grouping to all-members page -->\r
 263 \r
 264   <xsl:template match="table[preceding-sibling::h1[1][contains(text(),'Member List')]]">\r
 265     <table class="allmembers">\r
 266 \r
 267       <!-- We need to filter the table rows by looking for indications on the object type       -->\r
 268       <!-- The table has 3 acolumns:                                                            -->\r
 269       <!--    td[1] is the name of the object,                                                  -->\r
 270       <!--    td[2] is the name of the class the object is defined in                           -->\r
 271       <!--    td[3] contains additional flags                                                   -->\r
 272       <!--                                                                                      -->\r
 273       <!-- The conditions we have are:                                                          -->\r
 274       <!--                                                                                      -->\r
 275       <!--    contains(td[3],'static')        static member (variable or function)              -->\r
 276       <!--    contains(td[3],'protected')     protected member of arbitrary type                -->\r
 277       <!--    contains(td[3],'private')       private member of arbitrary type                  -->\r
 278       <!--    contains(td{3],'friend')        friend declaration (function or class)            -->\r
 279       <!--    contains(td[3],'pure virtual')  entry is a pure-virtual member function           -->\r
 280       <!--    starts-with(td[1]/text(),'(')   function entry (member, static or friend)         -->\r
 281       <!--    contains(td[1], 'typedef')      entry is a typdef                                 -->\r
 282       <!--    contains(td[1], 'enum ')        entry is enum type or enumerator                  -->\r
 283       <!--    contains(td[1], 'enum name')    entry is the name of an enum type                 -->\r
 284       <!--    contains(td[1], 'enum value')   entry is an enumerator value                      -->\r
 285       <!--    str:split(substring-before(concat(td[2]/a,'&lt;'),'&lt;'),'::')[position()=last()]==string(td[1]/a) -->\r
 286       <!--                                    entry is a constructor                            -->\r
 287       <!--    not(starts-with(td[1]/a,'~'))   entry is a destructor                             -->\r
 288 \r
 289       <xsl:variable name="public-static-memfn">\r
 290         <xsl:apply-templates select="tr[contains(td[3],'static')][not(contains(td[3],'protected'))][not(contains(td[3],'private'))][not(contains(td[3],'friend'))][starts-with(td[1]/text(),'(')]"/>\r
 291       </xsl:variable>\r
 292       <xsl:if test="string($public-static-memfn)">\r
 293         <tr><td colspan="3"><h2>Static Public Member Functions</h2></td></tr>\r
 294         <xsl:copy-of select="$public-static-memfn"/>\r
 295       </xsl:if>\r
 296 \r
 297       <xsl:variable name="public-static-var">\r
 298         <xsl:apply-templates select="tr[not(contains(td[1],'typedef'))][contains(td[3],'static')][not(contains(td[3],'protected'))][not(contains(td[3],'private'))][not(starts-with(td[1]/text(),'('))]"/>\r
 299       </xsl:variable>\r
 300       <xsl:if test="string($public-static-var)">\r
 301         <tr><td colspan="3"><h2>Static Public Attributes</h2></td></tr>\r
 302         <xsl:copy-of select="$public-static-var"/>\r
 303       </xsl:if>\r
 304       \r
 305       <xsl:variable name="public-memfn">\r
 306         <xsl:apply-templates select="tr[not(contains(td[1],'typedef'))][not(contains(td[3],'static'))][not(contains(td[3],'protected'))][not(contains(td[3],'private'))][not(contains(td[3],'friend'))][starts-with(td[1]/text(),'(')][str:split(substring-before(concat(td[2]/a,'&lt;'),'&lt;'),'::')[position()=last()]!=string(td[1]/a)][not(starts-with(td[1]/a,'~'))][not(contains(td[3],'pure virtual'))]"/>\r
 307       </xsl:variable>\r
 308       <xsl:if test="string($public-memfn)">\r
 309         <tr><td colspan="3"><h2>Public Member Functions</h2></td></tr>\r
 310         <xsl:copy-of select="$public-memfn"/>\r
 311       </xsl:if>\r
 312 \r
 313       <xsl:variable name="public-var">\r
 314         <xsl:apply-templates select="tr[not(contains(td[1],'typedef'))][not(contains(td[1],'enum '))][not(contains(td[3],'static'))][not(contains(td[3],'protected'))][not(contains(td[3],'private'))][not(starts-with(td[1]/text(),'('))]"/>\r
 315       </xsl:variable>\r
 316       <xsl:if test="string($public-var)">\r
 317         <tr><td colspan="3"><h2>Public Attributes</h2></td></tr>\r
 318         <xsl:copy-of select="$public-var"/>\r
 319       </xsl:if>\r
 320       \r
 321       <xsl:variable name="public-enum">\r
 322         <xsl:apply-templates select="tr[contains(td[1],'enum value')][not(contains(td[3],'protected'))][not(contains(td[3],'private'))]"/>\r
 323       </xsl:variable>\r
 324       <xsl:if test="string($public-enum)">\r
 325         <tr><td colspan="3"><h2>Public Enumerators</h2></td></tr>\r
 326         <xsl:copy-of select="$public-enum"/>\r
 327       </xsl:if>\r
 328       \r
 329       <xsl:variable name="public-type">\r
 330         <xsl:apply-templates select="tr[contains(td[1],'typedef') or contains(td[1],'enum name')][not(contains(td[3],'protected'))][not(contains(td[3],'private'))][not(contains(td[3],'friend'))]"/>\r
 331       </xsl:variable>\r
 332       <xsl:if test="string($public-type)">\r
 333         <tr><td colspan="r"><h2>Public Types</h2></td></tr>\r
 334         <xsl:copy-of select="$public-type"/>\r
 335       </xsl:if>\r
 336       \r
 337       <xsl:variable name="non-public">\r
 338         <xsl:apply-templates select="tr[contains(td[3],'protected') or contains(td[3],'private') or contains(td[3],'friend')][str:split(substring-before(concat(td[2]/a,'&lt;'),'&lt;'),'::')[position()=last()]!=string(td[1]/a)][not(starts-with(td[1]/a,'~'))][not(contains(td[3],'pure virtual'))]"/>\r
 339       </xsl:variable>\r
 340       <xsl:if test="string($non-public)">\r
 341         <tr><td colspan="3"><h2>Non-Public Members</h2></td></tr>\r
 342         <xsl:copy-of select="$non-public"/>\r
 343       </xsl:if>\r
 344 \r
 345     </table>\r
 346   </xsl:template>\r
 347 \r
 348   <xsl:template match="table[preceding-sibling::h1[1][contains(text(),'Member List')]]/tr/td[2]/a/text()[contains(.,'&lt;')]">\r
 349     <!-- this removes the template args form the second column to make the table more compact -->\r
 350     <xsl:value-of select="substring-before(.,'&lt;')"/>\r
 351   </xsl:template>\r
 352 \r
 353   <xsl:template match="table[preceding-sibling::h1[1][contains(text(),'Member List')]]/tr/td[1]/a/text()[contains(.,'::')]">\r
 354     <!-- for some weird reason, some members have a fully qualified name in the first column -->\r
 355     <!-- remove the qualification here -->\r
 356     <xsl:value-of select="str:split(.,'::')[position()=last()]"/>\r
 357   </xsl:template>\r
 358 \r
 359   <!-- Remove the automatically inserted search form (we build our own) -->\r
 360   <xsl:template match="li[form]"> \r
 361   </xsl:template>\r
 362 \r
 363   <!-- Add CSS class to alphabetical class index table -->\r
 364   <xsl:template match="table[preceding-sibling::*[1][self::div][@class='qindex']]">\r
 365     <xsl:call-template name="add-class">\r
 366       <xsl:with-param name="class">qindextable</xsl:with-param>\r
 367     </xsl:call-template>\r
 368   </xsl:template>\r
 369 \r
 370   <!-- Add CSS class to special paragraphs -->\r
 371 \r
 372   <xsl:template match="dl[dt/b/a/text()='Bug:']">\r
 373     <xsl:call-template name="add-class">\r
 374       <xsl:with-param name="class">xref-bug</xsl:with-param>\r
 375     </xsl:call-template>\r
 376   </xsl:template>\r
 377 \r
 378   <xsl:template match="dl[dt/b/a/text()='Fix:']">\r
 379     <xsl:call-template name="add-class">\r
 380       <xsl:with-param name="class">xref-fix</xsl:with-param>\r
 381     </xsl:call-template>\r
 382   </xsl:template>\r
 383 \r
 384   <xsl:template match="dl[dt/b/a/text()='Todo:']">\r
 385     <xsl:call-template name="add-class">\r
 386       <xsl:with-param name="class">xref-todo</xsl:with-param>\r
 387     </xsl:call-template>\r
 388   </xsl:template>\r
 389 \r
 390   <xsl:template match="dl[dt/b/a/text()='Idea:']">\r
 391     <xsl:call-template name="add-class">\r
 392       <xsl:with-param name="class">xref-idea</xsl:with-param>\r
 393     </xsl:call-template>\r
 394   </xsl:template>\r
 395 \r
 396   <xsl:template match="dl[dt/b/text()='Parameters:']|dl[dt/b/text()='Template Parameters:']">\r
 397     <xsl:call-template name="add-class">\r
 398       <xsl:with-param name="class">parameters</xsl:with-param>\r
 399     </xsl:call-template>\r
 400   </xsl:template>\r
 401 \r
 402   <xsl:template match="dl[dt/b/text()='Implementation note:']">\r
 403     <xsl:call-template name="add-class">\r
 404       <xsl:with-param name="class">implementation</xsl:with-param>\r
 405     </xsl:call-template>\r
 406   </xsl:template>\r
 407 \r
 408   <xsl:template match="p[starts-with(text(),'Definition at line ')]">\r
 409     <xsl:call-template name="add-class">\r
 410       <xsl:with-param name="class">sourceline</xsl:with-param>\r
 411     </xsl:call-template>\r
 412   </xsl:template>\r
 413 \r
 414   <xsl:template match="div[@class='memdoc']/p[starts-with(text(),'References ')]">\r
 415     <xsl:call-template name="add-class">\r
 416       <xsl:with-param name="class">references</xsl:with-param>\r
 417     </xsl:call-template>\r
 418   </xsl:template>\r
 419 \r
 420   <xsl:template match="div[@class='memdoc']/p[starts-with(text(),'Referenced by ')]">\r
 421     <xsl:call-template name="add-class">\r
 422       <xsl:with-param name="class">referencedby</xsl:with-param>\r
 423     </xsl:call-template>\r
 424   </xsl:template>\r
 425 \r
 426   <xsl:template match="div[@class='memdoc']/p[starts-with(text(),'Reimplemented from ')]">\r
 427     <xsl:call-template name="add-class">\r
 428       <xsl:with-param name="class">reimplementedfrom</xsl:with-param>\r
 429     </xsl:call-template>\r
 430   </xsl:template>\r
 431 \r
 432   <xsl:template match="div[@class='memdoc']/p[starts-with(text(),'Reimplemented in ')]">\r
 433     <xsl:call-template name="add-class">\r
 434       <xsl:with-param name="class">reimplementedin</xsl:with-param>\r
 435     </xsl:call-template>\r
 436   </xsl:template>\r
 437 \r
 438   <xsl:template match="div[@class='memdoc']/p[starts-with(text(),'Implemented in ')]">\r
 439     <xsl:call-template name="add-class">\r
 440       <xsl:with-param name="class">implementedin</xsl:with-param>\r
 441     </xsl:call-template>\r
 442   </xsl:template>\r
 443 \r
 444   <!-- Break the following lists after each komma -->\r
 445 \r
 446   <xsl:template match="p[starts-with(text(),'Inherited by ')]">\r
 447     <xsl:call-template name="break-comma"/>\r
 448   </xsl:template>\r
 449 \r
 450   <xsl:template match="p[starts-with(text(),'Inherits ')]">\r
 451     <xsl:call-template name="break-comma"/>\r
 452   </xsl:template>\r
 453 \r
 454   <!-- Add CSS class to the member overview table of a class documentation -->\r
 455   <xsl:template match="table[descendant::td[@class='memItemLeft']]">\r
 456     <xsl:call-template name="add-class">\r
 457       <xsl:with-param name="class">members</xsl:with-param>\r
 458     </xsl:call-template>\r
 459   </xsl:template>\r
 460 \r
 461   <!-- Add CSS class to literal links (links, where link text and href attribute are the same -->\r
 462   <xsl:template match="a[@href=string(current())]" priority="1">\r
 463     <xsl:call-template name="add-class">\r
 464       <xsl:with-param name="class">literal</xsl:with-param>\r
 465     </xsl:call-template>\r
 466   </xsl:template>\r
 467 \r
 468   <!-- Add CSS class to external links -->\r
 469   <xsl:template match="a[contains(@href,'http://')]">\r
 470     <xsl:call-template name="add-class">\r
 471       <xsl:with-param name="class">ext</xsl:with-param>\r
 472     </xsl:call-template>\r
 473   </xsl:template>\r
 474 \r
 475   <!-- Add CSS class to anchor-only links -->\r
 476   <xsl:template match="a[not(@href)]">\r
 477     <xsl:call-template name="add-class">\r
 478       <xsl:with-param name="class">anchor</xsl:with-param>\r
 479     </xsl:call-template>\r
 480   </xsl:template>\r
 481 \r
 482   <!-- Add CSS class to the brief documentation paragraph of the member documentation -->\r
 483   <xsl:template match="div[@class='memdoc']/p[1]">\r
 484     <xsl:call-template name="add-class">\r
 485       <xsl:with-param name="class">memtitle</xsl:with-param>\r
 486     </xsl:call-template>\r
 487   </xsl:template>\r
 488 \r
 489   <!-- Remove external items from the namespace index -->\r
 490   <xsl:template match="div[@id='content2']/table[contains(preceding-sibling::h1/text(),'Namespace Reference')]/tr[td[@class='memItemRight']/a[1][@class='elRef'][@doxygen]]">\r
 491   </xsl:template>\r
 492   \r
 493   <!-- Remove [external] references from the modules page -->\r
 494   <xsl:template match="div[@id='content2']/ul/li[a/@class='elRef'][a/@doxygen][code/text()='[external]'][not(ul)]">\r
 495   </xsl:template>\r
 496 \r
 497   <!-- Insert 'senf/'  into include paths -->\r
 498   <xsl:template match="code[starts-with(text(),'#include &lt;')]/a">\r
 499     <xsl:copy>\r
 500       <xsl:call-template name="copy-attributes"/>\r
 501       <xsl:text>senf/</xsl:text>\r
 502       <xsl:apply-templates/>\r
 503     </xsl:copy>\r
 504   </xsl:template>\r
 505 \r
 506 </xsl:stylesheet>\r