site_scons/SENFSCons.py

   1 import os.path, glob
   2 import SCons.Options, SCons.Environment, SCons.Script.SConscript, SCons.Node.FS
   3 import SCons.Defaults, SCons.Action
   4 from SCons.Script import *
   5
   6 def Glob(env, exclude=[], subdirs=[]):
   7     testSources = glob.glob("*.test.cc")
   8     sources = [ x for x in glob.glob("*.cc") if x not in testSources and x not in exclude ]
   9     for subdir in subdirs:
  10         testSources += glob.glob(os.path.join(subdir,"*.test.cc"))
  11         sources += [ x for x in glob.glob(os.path.join(subdir,"*.cc"))
  12                      if x not in testSources and x not in exclude ]
  13     includes = []
  14     for d in [ '.' ] + subdirs:
  15         for f in os.listdir(d):
  16             ext = '.' + f.split('.',1)[-1]
  17             p = os.path.join(d,f)
  18             if ext in env['CPP_INCLUDE_EXTENSIONS'] \
  19                and ext not in env['CPP_EXCLUDE_EXTENSIONS'] \
  20                and p not in exclude:
  21                 includes.append(p)
  22     return ( sources, testSources, includes )
  23
  24 def Doxygen(env, doxyfile = "Doxyfile", extra_sources = []):
  25     # There is one small problem we need to solve with this builder: The Doxygen builder reads
  26     # the Doxyfile and thus depends on the environment variables set by doclib/doxygen.sh. We
  27     # thus have to provide all necessary definitions here manually via DOXYENV !
  28
  29     if type(doxyfile) is type(""):
  30         doxyfile = env.File(doxyfile)
  31
  32     # Module name is derived from the doxyfile path
  33     # Utils/Console/Doxyfile -> Utils_Console
  34     module = doxyfile.dir.get_path(env.Dir('#')).replace('/','_')
  35     if module == '.' : module = "Main"
  36
  37     # Rule to generate tagfile
  38     # (need to exclude the 'clean' case, otherwise we'll have duplicate nodes)
  39     if not env.GetOption('clean'):
  40         tagfile = env.Doxygen(doxyfile,
  41                               DOXYOPTS = [ '--tagfile-name', '"${MODULE}.tag"',
  42                                            '--tagfile' ],
  43                               DOXYENV  = { 'TOPDIR'          : env.Dir('#').abspath,
  44                                            'output_dir'      : 'doc',
  45                                            'html_dir'        : 'html',
  46                                            'html'            : 'NO',
  47                                            'generate_tagfile': 'doc/${MODULE}.tag' },
  48                               MODULE   = module )
  49         env.Append(ALL_TAGFILES = tagfile[0].abspath)
  50         env.Depends(tagfile, [ env.File('#/doclib/doxygen.sh'),
  51                                env.File('#/doclib/tag-munge.xsl') ])
  52
  53     # Rule to generate HTML documentation
  54     doc = env.Doxygen(doxyfile,
  55                       DOXYOPTS = [ '--tagfiles', '"$ALL_TAGFILES"',
  56                                    '--tagfile-name', '"${MODULE}.tag"',
  57                                    '--html' ],
  58                       MODULE   = module,
  59                       DOXYENV  = { 'TOPDIR'          : env.Dir('#').abspath,
  60                                    'tagfiles'        : '${ALL_TAGFILES}',
  61                                    'output_dir'      : 'doc',
  62                                    'html_dir'        : 'html',
  63                                    'html'            : 'YES' } )
  64     env.Depends(doc, [ env.File('#/doclib/doxygen.sh'),
  65                        env.File('#/doclib/html-munge.xsl') ])
  66
  67     # Copy the extra_sources (the images) into the documentation directory
  68     # (need to exclude the 'clean' case otherwise there are multiple ways to clean the copies)
  69     if not env.GetOption('clean'):
  70         if extra_sources:
  71             env.Depends(doc, env.CopyToDir(doc[0].dir, extra_sources))
  72
  73     # Install documentation into DOCINSTALLDIR
  74     l = len(env.Dir('#').abspath)
  75     env.Install(env.Dir('$DOCINSTALLDIR').Dir(doc[0].dir.get_path('#')), doc[0].dir)
  76
  77     # Useful aliases
  78     env.Alias('all_docs', doc)
  79     env.Clean('all_docs', doc)
  80     env.Clean('all', doc)
  81
  82     return doc
  83
  84 def AllIncludesHH(env, exclude=[]):
  85     exclude = exclude[:] + ['all_includes.hh'] # Make a copy !!
  86     headers = [ f for f in glob.glob("*.hh")
  87                 if f not in exclude and not f.endswith('.test.hh') ]
  88     headers.sort()
  89     target = env.File("all_includes.hh")
  90     file(target.abspath,"w").write("".join([ '#include "%s"\n' % f
  91                                              for f in headers ]))
  92     env.Clean('all', target)
  93
  94 ###########################################################################
  95 # The following functions serve as simple macros for most SConscript files
  96 #
  97 # If you need to customize these rules, copy-and-paste the code into the
  98 # SConscript file and adjust at will (don't to forget to replace the
  99 # parameters with their actual value. Parameters are marked with ((name)) )
 100
 101 def AutoRules(env, exclude=[], subdirs=[], doc_extra_sources = []):
 102     import SENFSCons, glob, os.path
 103
 104     sources, tests, includes      = SENFSCons.Glob(env, exclude=((exclude)), subdirs=((subdirs)) )
 105     subscripts                    = glob.glob("*/SConscript")
 106
 107     if sources                    : env.Append(ALLOBJECTS = env.Object(sources))
 108     if tests                      : env.BoostUnitTest('test', tests)
 109     if includes                   : env.InstallSubdir('$INCLUDEINSTALLDIR', includes)
 110     if os.path.exists("Doxyfile") : SENFSCons.Doxygen(env, extra_sources=((doc_extra_sources)) )
 111     if subscripts                 : SConscript(glob.glob("*/SConscript"))
 112
 113
 114 def AutoPacketBundle(env, name, exclude=[], subdirs=[], doc_extra_sources=[]):
 115     import SENFSCons, glob, os.path
 116
 117     sources, tests, includes      = SENFSCons.Glob(env, exclude=((exclude)), subdirs=((subdirs)) )
 118     subscripts                    = glob.glob("*/SConscript")
 119
 120     objects = env.Object(sources)
 121     cobject = env.CombinedObject(name, objects)
 122
 123     env.Default(cobject)
 124     env.Append(ALLOBJECTS = objects, PACKET_BUNDLES = cobject)
 125     env.Install('$OBJINSTALLDIR', cobject)
 126
 127     if tests                      : env.BoostUnitTest('test', tests + cobject)
 128     if includes                   : env.InstallSubdir('$INCLUDEINSTALLDIR', includes)
 129     if os.path.exists("Doxyfile") : SENFSCons.Doxygen(env, extra_sources=((doc_extra_sources)) )
 130     if subscripts                 : SConscript(glob.glob("*/SConscript"))