site_scons/SENFSCons.py

   1 import os.path, glob
   2 import SCons.Options, SCons.Environment, SCons.Script.SConscript, SCons.Node.FS
   3 import SCons.Defaults, SCons.Action
   4 from SCons.Script import *
   5
   6 def Glob(env, exclude=[], subdirs=[]):
   7     testSources = glob.glob("*.test.cc")
   8     sources = [ x for x in glob.glob("*.cc") if x not in testSources and x not in exclude ]
   9     for subdir in subdirs:
  10         testSources += glob.glob(os.path.join(subdir,"*.test.cc"))
  11         sources += [ x for x in glob.glob(os.path.join(subdir,"*.cc"))
  12                      if x not in testSources and x not in exclude ]
  13     includes = []
  14     for d in [ '.' ] + subdirs:
  15         for f in os.listdir(d):
  16             ext = '.' + f.split('.',1)[-1]
  17             p = os.path.join(d,f)
  18             if ext in env['CPP_INCLUDE_EXTENSIONS'] \
  19                and ext not in env['CPP_EXCLUDE_EXTENSIONS'] \
  20                and p not in exclude:
  21                 includes.append(p)
  22     return ( sources, testSources, includes )
  23
  24 def Doxygen(env, doxyfile = "Doxyfile", extra_sources = []):
  25     # There is one small problem we need to solve with this builder: The Doxygen builder reads
  26     # the Doxyfile and thus depends on the environment variables set by site_scons/lib/doxygen.sh.
  27     # We thus have to provide all necessary definitions here manually via DOXYENV !
  28
  29     if type(doxyfile) is type(""):
  30         doxyfile = env.File(doxyfile)
  31
  32     # Module name is derived from the doxyfile path
  33     # Utils/Console/Doxyfile -> Utils_Console
  34     module = doxyfile.dir.get_path(env.Dir('#')).replace('/','_')
  35     if module == '.' : module = "Main"
  36
  37     # Rule to generate tagfile
  38     # (need to exclude the 'clean' case, otherwise we'll have duplicate nodes)
  39     if not env.GetOption('clean'):
  40         tagfile = env.Doxygen(doxyfile,
  41                               DOXYOPTS = [ '--tagfile-name', '"${MODULE}.tag"',
  42                                            '--tagfile' ],
  43                               DOXYENV  = { 'TOPDIR'          : env.Dir('#').abspath,
  44                                            'output_dir'      : 'doc',
  45                                            'html_dir'        : 'html',
  46                                            'html'            : 'NO',
  47                                            'generate_tagfile': 'doc/${MODULE}.tag' },
  48                               MODULE   = module )
  49         env.Append(ALL_TAGFILES = [ tagfile[0].abspath ])
  50         env.Depends(tagfile, [ env.File('#/site_scons/lib/doxygen.sh'),
  51                                env.File('#/site_scons/lib/tag-munge.xsl') ])
  52
  53         env.Install(env.Dir('$DOCINSTALLDIR').Dir(tagfile[0].dir.get_path(env.Dir('#'))),
  54                     tagfile[0])
  55
  56     # Rule to generate HTML documentation
  57     doc = env.Doxygen(doxyfile,
  58                       DOXYOPTS = [ '--tagfiles', '"$ALL_TAGFILES"',
  59                                    '--tagfile-name', '"${MODULE}.tag"',
  60                                    '--html' ],
  61                       MODULE   = module,
  62                       DOXYENV  = { 'TOPDIR'          : env.Dir('#').abspath,
  63                                    'tagfiles'        : '${ALL_TAGFILES}',
  64                                    'output_dir'      : 'doc',
  65                                    'html_dir'        : 'html',
  66                                    'html'            : 'YES' } )
  67     env.Depends(doc, [ env.File('#/site_scons/lib/doxygen.sh'),
  68                        env.File('#/site_scons/lib/html-munge.xsl') ])
  69
  70     # Copy the extra_sources (the images) into the documentation directory
  71     # (need to exclude the 'clean' case otherwise there are multiple ways to clean the copies)
  72     if extra_sources:
  73         if env.GetOption('clean'):
  74             env.Depends(doc, extra_sources)
  75         else:
  76             env.Depends(doc, env.CopyToDir(doc[0].dir, extra_sources))
  77
  78     # Install documentation into DOCINSTALLDIR
  79     env.InstallDir(env.Dir('$DOCINSTALLDIR').Dir(doc[0].dir.dir.get_path(env.Dir('#'))), doc[0].dir,
  80                    FILTER_SUFFIXES=['.html','.css','.png','.php','.idx'])
  81
  82     # Useful aliases
  83     env.Alias('all_docs', doc)
  84     env.Clean(env.Alias('all_docs'), doc)
  85     env.Clean(env.Alias('all'), doc)
  86
  87     return doc
  88
  89 def AllIncludesHH(env, exclude=[]):
  90     exclude = exclude[:] + ['all_includes.hh'] # Make a copy !!
  91     headers = [ f for f in glob.glob("*.hh")
  92                 if f not in exclude and not f.endswith('.test.hh') ]
  93     headers.sort()
  94     target = env.File("all_includes.hh")
  95     file(target.abspath,"w").write("".join([ '#include "%s"\n' % f
  96                                              for f in headers ]))
  97     env.Clean(env.Alias('all'), target)
  98
  99 ###########################################################################
 100 # The following functions serve as simple macros for most SConscript files
 101 #
 102 # If you need to customize these rules, copy-and-paste the code into the
 103 # SConscript file and adjust at will (don't forget to replace the
 104 # parameters with their actual value. Parameters are marked with ((name)) )
 105
 106 def AutoRules(env, exclude=[], subdirs=[], doc_extra_sources = []):
 107     import SENFSCons
 108
 109     sources, tests, includes = SENFSCons.Glob(env, exclude=((exclude)), subdirs=((subdirs)) )
 110     subscripts               = env.Glob("*/SConscript")
 111     doxyfile                 = env.Glob("Doxyfile")
 112
 113     if sources               : env.Append(ALLOBJECTS = env.Object(sources))
 114     if tests                 : env.BoostUnitTest('test', tests)
 115     if includes              : env.InstallSubdir('$INCLUDEINSTALLDIR', includes)
 116     if doxyfile              : SENFSCons.Doxygen(env, extra_sources=((doc_extra_sources)) )
 117     if subscripts            : SConscript(subscripts)
 118
 119
 120 def AutoPacketBundle(env, name, exclude=[], subdirs=[], doc_extra_sources=[]):
 121     import SENFSCons
 122
 123     sources, tests, includes = SENFSCons.Glob(env, exclude=((exclude)), subdirs=((subdirs)) )
 124     subscripts               = env.Glob("*/SConscript")
 125     doxyfile                 = env.Glob("Doxyfile")
 126
 127     objects = env.Object(sources)
 128     cobject = env.CombinedObject('${LOCALLIBDIR}/${NAME}${OBJADDSUFFIX}', objects, NAME=((name)))
 129
 130     env.Default(cobject)
 131     env.Append(ALLOBJECTS = objects, PACKET_BUNDLES = cobject)
 132     env.Install('$OBJINSTALLDIR', cobject)
 133
 134     if tests                 : env.BoostUnitTest('test', tests + cobject)
 135     if includes              : env.InstallSubdir('$INCLUDEINSTALLDIR', includes)
 136     if doxyfile              : SENFSCons.Doxygen(env, extra_sources=((doc_extra_sources)) )
 137     if subscripts            : SConscript(subscripts)